***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Oct 27, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJA3461-AU   D   G   S
*****param & model definition***
.model  dmos  pmos(
+    l = 1e-6		  w = 1e-6	level = 3
+  vto = -2.02		 kp = 3.8)
.model  dds   d(
+   is = 4.432e-12	  n = 1.103	   rs = 1.281e-2		ikf = 2.121e-1
+   eg = 0.973	     trs1 = 3.874e-3	 tikf = -5.2e-3)
.model  dbody d(
+   is = 4.432e-12	  n = 1.103	   rs = 1.281e-2		ikf = 2.121e-1
+  cjo = 5.458e-11	  m = 6.206e-1	   vj = 6.234e-1
+   bv = 66		ibv = 250e-6	 tbv1 = 5.203e-4		 tt = 25n)
.model  inter  pmos(
+  vto = 0		 kp = 10	level = 1)
.model  dgd    d(
+  cjo = 9.610e-11	  m = 2.636e-1	   vj = 3.986e-1)
.param
+  cgs = 4.102e-10	cgd = 9.625e-11
+   rd = 5.641e-2	 ra = 2.452e-2	  trd = 1.106e-2
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}   
egv	  3  2t   table   {v(S, 1t)}
+((0   , 0   ),
+ (0.5 , 0.5 ),
+ (1   , 1   ),
+ (2   , 2   ),
+ (2.5 , 2.5 ),
+ (3   , 3   ),
+ (4   , 4   ),
+ (4.5 , 4.5 ),
+ (5   , 4.95),
+ (6   , 5.5 ),
+ (8   , 6   ),
+ (10  , 6.5 ),
+ (20  , 7   ),
+ (22  , 7   ))
egt	  1  2t   value = {8.687e-4*limit(v(2t,3),-4.5,0)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd}
dds	  4   3   dds
dbody	  D   3   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1     1t   8   6   6   inter
e1      8   6   4   1t  2
cgd	7   4   {cgd}   
rcgd    7   4   10meg
dgd     4   6   dgd
rdgd    4   6   10meg
m2      7   9  1t  1t   inter
e2      9  1t   4  1t   -2
.ends
*$
